IF函數會根據設定的條件公式判斷條件是否一致，並依判斷結果變更傳回的值。

IF(條件公式, 為 True 時傳回的值, 為 False 時傳回的值)

在IF函數中指定「條件公式」、「為 True 時傳回的值」、「為 False 時傳回的值」作為參數。
IF函數可使用階層構造（巢狀）記載多個函數或計算公式。較長的計算公式可以換行或縮排，方便查看。

「條件公式」參數可以指定欄位代碼或值，以及組合比較運算符號的條件公式。
可以在條件公式中使用下列運算符號。

• =
• !=
• <>
• <
• <=
• >
• >=

比較數值型的欄位（數值欄位等）時，可使用上述所有運算符號。
比較字串型的欄位（單行文字方塊欄位等）時，只能使「＝」「!=」「<>」。只能比較字串型欄位「是否相等」。

關於欄位的資料類型，請參閱「欄位的資料類型」。

「為 True 時傳回的值」及「為 False 時傳回的值」指定要傳回數值型、字串型、邏輯型結果的計算公式或值。
若要直接指定字串，用雙引號（"）括住。

IF(住宿="有", "需要出差申請", "不需出差申請")

若要將計算結果顯示為字串，請在單行文字方塊欄位中設定計算公式。

若要讓傳回的值顯示為空白，記載「""」。

以下範例的計算公式為若「個數」欄位為0，顯示為空白。若「個數」欄位不為0，顯示「個數」欄位與「單價」欄位相乘的結果。

IF(個數=0, "", 單價*個數)

若要將條件指定為要計算的欄位是否空白，在計算公式中指定空字串（""）。
例如，若指定「數值欄位=""」，數值欄位空白時將判斷為 True，輸入「0」時將判斷為 False。

以下範例的計算公式為若「個數」欄位空白，顯示「未輸入」。若「個數」欄位有輸入內容，顯示「個數」欄位與「單價」欄位相乘的結果。

IF(個數="", "未輸入", 單價*個數)

若要將計算結果顯示為字串，請在單行文字方塊欄位中設定計算公式。

IF函數可與CONTAINS函數、AND、OR、NOT函數組合，用來設定更詳細的條件公式。
詳情請參閱各函數的頁面。

若參照的數值型欄位空白，將視為「0」進行計算。 若參照的字串型欄位空白，將視為空字串（""）進行計算。

在計算公式中指定欄位時，請指定欄位代碼作為參數，而非欄位名稱。
以下範例中，欄位代碼與欄位名稱完全相同。

以下範例的計算公式為若「合計」欄位為80分以上顯示「OK」，未滿80分則顯示「NG」。

IF(合計>=80,"OK","NG")

在單行文字方塊欄位中設定計算公式。配置單行文字方塊欄位，勾選「自動計算」，輸入計算公式。

以下範例的計算公式為若「總金額」欄位為1,000日圓以上，顯示折扣15%的價格，未滿1,000日圓則顯示總金額。

IF(總金額>=1000, 總金額*0.85, 總金額)

以下範例的計算公式為若「早餐」欄位選擇「有」，顯示住宿費9,000日圓，選擇「無」則顯示住宿費7,000日圓。

IF(早餐="有", 9000, 7000)

「早餐」欄位設為下拉式選單欄位或選項按鈕欄位。
若要在條件公式中指定下拉式選單或選項按鈕，用雙引號（"）括住項目名稱。

以下範例的計算公式為根據「預算」欄位及「績效」欄位計算預算比例。
若「預算」欄位為「0」，將欄位顯示為空白；若數字大於「0」，計算「預算比例」。

IF(預算>0, (績效/預算)*100, "")

若計算公式中只記載計算預算比例的除法「績效/預算」，預算為「0」時，分母將為「0」並發生錯誤。因此，此計算公式中使用IF函數進行區分，預算為「0」時不進行計算。

以下範例的計算公式為若「合計」欄位大於等於「目標值」欄位，顯示「達成」；若「合計」欄位小於「目標值」欄位，則顯示「未達成」。

IF(合計>=目標值,"達成","未達成")

在單行文字方塊欄位中設定計算公式。配置單行文字方塊欄位，勾選「自動計算」，輸入計算公式。

以下範例的計算公式為若考試的分數為100分顯示滿分，80分以上顯示合格，否則顯示不合格。

IF(分數=100,"滿分",IF(分數>=80,"合格","不合格"))

在單行文字方塊欄位中設定計算公式。配置單行文字方塊欄位，勾選「自動計算」，輸入計算公式。